ERC1155 Token Bridge

Deposit ERC1155 tokens from L1

ERC1155 bridging from L1 to L2 is done via the L1ERC1155Gateway. Similarly to ERC721 bridging, we don’t use a router but the depositERC1155 function on the Gateway directly.

Creating an ERC1155 token on L2

Similar to ERC721 bridging, in order to bridge ERC1155 tokens, a contract compatible with the IScrollERC1155 standard has to be launched and mapped on a L1ERC1155Gateway and L2ERC1155Gateway on both L1 and L2 respectively. This contract has to grant permission to the Gateway on L2 to mint when a token is deposited and burn when the token is withdrawn.

The following interface is the IScrollERC1155 needed for deploying ERC1155 tokens compatible with the L2ERC1155Gateway on L2.

interface IScrollERC1155 {
  /// @notice Return the address of Gateway the token belongs to.
  function gateway() external view returns (address);

  /// @notice Return the address of counterpart token.
  function counterpart() external view returns (address);

  /// @notice Mint some token to recipient's account.
  /// @dev Gateway Utilities, only gateway contract can call
  /// @param _to The address of recipient.
  /// @param _tokenId The token id to mint.
  /// @param _amount The amount of token to mint.
  /// @param _data The data passed to recipient
  function mint(address _to, uint256 _tokenId, uint256 _amount, bytes memory _data) external;

  /// @notice Burn some token from account.
  /// @dev Gateway Utilities, only gateway contract can call
  /// @param _from The address of account to burn token.
  /// @param _tokenId The token id to burn.
  /// @param _amount The amount of token to burn.
  function burn(address _from, uint256 _tokenId, uint256 _amount) external;

  /// @notice Batch mint some token to recipient's account.
  /// @dev Gateway Utilities, only gateway contract can call
  /// @param _to The address of recipient.
  /// @param _tokenIds The list of token ids to mint.
  /// @param _amounts The list of corresponding amount of token to mint.
  /// @param _data The data passed to recipient
  function batchMint(
    address _to,
    uint256[] calldata _tokenIds,
    uint256[] calldata _amounts,
    bytes calldata _data
  ) external;

  /// @notice Batch burn some token from account.
  /// @dev Gateway Utilities, only gateway contract can call
  /// @param _from The address of account to burn token.
  /// @param _tokenIds The list of token ids to burn.
  /// @param _amounts The list of corresponding amount of token to burn.
  function batchBurn(address _from, uint256[] calldata _tokenIds, uint256[] calldata _amounts) external;
}

Adding an ERC1155 token to the Scroll Bridge

All assets can be bridged securely and permissionlessly through Gateway contracts deployed by any developer. However, Scroll also manages an ERC1155 Gateway contract where all NFTs created by the community are welcome. Being part of the Scroll-managed Gateway means you won’t need to deploy the Gateway contracts, and your token will appear in the Scroll frontend. To be part of the Scroll Gateway, you must contact the Scroll team to add the token to both L1 and L2 Gateway contracts. To do so, follow the instructions on the token lists repository to add your token to the Scroll official frontend.

Withdraw ERC1155 tokens from L2

The L2ERC1155Gateway contract is used to send tokens from L2 to L1. Before bridging, the L2ERC1155Gateway contract has to be approved by the token contract. Once that is done, withdrawERC1155 can be called to perform the asset bridge.

L1ERC1155Gateway API

Please visit the npm library for the complete Scroll contract API documentation.

depositERC1155

function depositERC1155(
  address _token,
  address _to,
  uint256 _tokenId,
  uint256 _amount,
  uint256 _gasLimit
) external payable;

Deposit an ERC1155 token from L1 to a recipient’s account on L2.

updateTokenMapping

function updateTokenMapping(address _l1Token, address _l2Token) external;

Update the mapping that connects an ERC1155 token contract from L1 to L2.

L2ERC1155Gateway API

withdrawERC1155

function withdrawERC1155(address token, address to, uint256 tokenId, uint256 amount, uint256 gasLimit) external payable;

Send ERC1155 tokens from L2 to a recipient’s account on L1.

updateTokenMapping

function updateTokenMapping(address _l1Token, address _l2Token) external;

Update the mapping that connects an ERC1155 token contract from L2 to L1.